Repository navigation
Expand file tree
/
Copy pathCMakeLists.txt
More file actions
228 lines (186 loc) · 7.59 KB
/
Copy pathCMakeLists.txt
File metadata and controls
228 lines (186 loc) · 7.59 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
cmake_minimum_required(VERSION 3.24)
if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
set(NUMERICAL_TOOLBOX_STANDALONE On)
endif()
option(CMAKE_COMPILE_WARNING_AS_ERROR "Enable warnings-as-error" On)
option(NUMERICAL_TOOLBOX_INCLUDE_DEFAULT_INIT "Include default initialization code; turn off when providing custom initialization" On)
option(NUMERICAL_TOOLBOX_BUILD_SIMULATOR "Enable build of the Qt simulator applications" Off)
option(NUMERICAL_TOOLBOX_BUILD_TESTS "Enable build of the tests" Off)
option(NUMERICAL_TOOLBOX_BUILD_INTEGRATION_TESTS "Enable build of the cucumber integration tests" Off)
option(NUMERICAL_TOOLBOX_ENABLE_OPTIMIZATIONS "Enable compiler optimizations for numerical routines" On)
option(NUMERICAL_TOOLBOX_EMBEDDED_OPTIMIZATIONS "Build the toolbox's own targets with the embedded floating-point model (-ffast-math -fno-finite-math-only)" Off)
option(NUMERICAL_TOOLBOX_ENABLE_CUSTOM_MATH "Enable platform-specific math overrides (e.g. MathArm.hpp for ARM targets)" Off)
if (NUMERICAL_TOOLBOX_BUILD_TESTS)
# CTest cannot be included before the first project() statement, but Embedded Infastructure
# Library needs to see that test utilities need to be built.
set(BUILD_TESTING On)
add_definitions(-DNUMERICAL_TOOLBOX_ENABLE_ASSERTIONS=1)
endif()
if (EMIL_ENABLE_COVERAGE)
add_definitions(-DNUMERICAL_TOOLBOX_COVERAGE_BUILD=1)
endif()
list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
include(NumericalHeaderLibrary)
include(NumericalCompilerOptions)
add_definitions(-DEMIL_ENABLE_TRACING=1)
if (NUMERICAL_TOOLBOX_STANDALONE)
include(FetchContent)
FetchContent_Declare(
emil
GIT_REPOSITORY https://github.com/embedded-pro/embedded-infra-lib.git
GIT_TAG b1056e80ab5376d7e4ee821c5b3c5680bc01f751 # Unreleased
)
set(EMIL_INCLUDE_MBEDTLS Off CACHE BOOL "" FORCE)
set(EMIL_INCLUDE_ECHO Off CACHE BOOL "" FORCE)
set(EMIL_FETCH_ECHO_COMPILERS Off CACHE BOOL "" FORCE)
set(EMIL_BUILD_ECHO_COMPILERS Off CACHE BOOL "" FORCE)
set(EMIL_ENABLE_DOCKER_TOOLS Off CACHE BOOL "" FORCE)
FetchContent_MakeAvailable(emil)
if (NUMERICAL_TOOLBOX_BUILD_SIMULATOR)
FetchContent_Declare(
ui
GIT_REPOSITORY https://github.com/embedded-pro/ui-cpp.git
GIT_TAG main
)
# Set explicitly rather than inferred by ui-cpp from a consumer's simulator flag: e-foc
# configures its Qt tools on every host build, so there is no consumer flag that means
# the same thing everywhere.
set(UI_BUILD_QT_BACKEND On CACHE BOOL "" FORCE)
FetchContent_MakeAvailable(ui)
endif()
endif()
project(numerical-toolbox LANGUAGES C CXX ASM VERSION 3.1.2) # x-release-please-version
set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED On)
if(NUMERICAL_TOOLBOX_STANDALONE AND CMAKE_C_COMPILER_ID MATCHES "GNU|Clang")
set(CMAKE_C_FLAGS_DEBUG "-Og -g" CACHE STRING "C Debug flags" FORCE)
set(CMAKE_CXX_FLAGS_DEBUG "-Og -g" CACHE STRING "C++ Debug flags" FORCE)
endif()
if (NUMERICAL_TOOLBOX_STANDALONE)
execute_process(
COMMAND git config --global url.https://github.com/.insteadOf git@github.com:
RESULT_VARIABLE GIT_CONFIG_RESULT
OUTPUT_QUIET
ERROR_QUIET
)
endif()
set_directory_properties(PROPERTY USE_FOLDERS ON)
# When building usb-host by itself do not exclude any targets from all
# Libraries will only be excluded from all when usb-host is a consumed as a dependency.
if (NUMERICAL_TOOLBOX_STANDALONE)
set(NUMERICAL_TOOLBOX_EXCLUDE_FROM_ALL "")
else()
set(NUMERICAL_TOOLBOX_EXCLUDE_FROM_ALL "EXCLUDE_FROM_ALL")
endif()
if (NUMERICAL_TOOLBOX_BUILD_TESTS)
include(CTest)
emil_enable_testing()
elseif (NUMERICAL_TOOLBOX_BUILD_INTEGRATION_TESTS)
include(CTest)
endif()
include(QemuHelpers)
if (NUMERICAL_TOOLBOX_EMBEDDED_OPTIMIZATIONS)
numerical_toolbox_enable_embedded_optimizations()
endif()
add_subdirectory(numerical)
if (NUMERICAL_TOOLBOX_BUILD_SIMULATOR)
add_subdirectory(simulator)
endif()
if (NUMERICAL_TOOLBOX_BUILD_INTEGRATION_TESTS AND NUMERICAL_TOOLBOX_STANDALONE)
add_subdirectory(integration-tests)
endif()
emil_clangformat_directories(numerical DIRECTORIES .)
if (NUMERICAL_TOOLBOX_BUILD_SIMULATOR)
emil_clangformat_directories(simulator DIRECTORIES .)
endif()
emil_coverage_targets(DIRECTORIES .)
if (NUMERICAL_TOOLBOX_STANDALONE)
emil_folderize_all_targets()
endif()
include(GNUInstallDirs)
include(CMakePackageConfigHelpers)
set(NUMERICAL_TOOLBOX_INSTALL_TARGETS
numerical.analysis
numerical.analysis.windowing
numerical.control_analysis
numerical.controllers.interfaces
numerical.controllers.implementations
numerical.estimators
numerical.estimators.offline
numerical.estimators.online
numerical.filters.active
numerical.filters.passive
numerical.math
numerical.nonlinear_control
numerical.optimization
numerical.regularization
numerical.robust_control
numerical.solver
)
list(APPEND NUMERICAL_TOOLBOX_INSTALL_TARGETS infra.util)
foreach(numerical_target ${NUMERICAL_TOOLBOX_INSTALL_TARGETS})
if (TARGET ${numerical_target})
install(TARGETS ${numerical_target}
EXPORT NumericalToolboxTargets
ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
)
endif()
endforeach()
install(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/numerical
DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
FILES_MATCHING
PATTERN "*.hpp"
PATTERN "test" EXCLUDE
PATTERN "test_doubles" EXCLUDE
)
if (NUMERICAL_TOOLBOX_STANDALONE AND DEFINED emil_SOURCE_DIR)
install(DIRECTORY ${emil_SOURCE_DIR}/infra
DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
FILES_MATCHING
PATTERN "*.hpp"
PATTERN "test" EXCLUDE
PATTERN "test_doubles" EXCLUDE
)
endif()
install(EXPORT NumericalToolboxTargets
FILE NumericalToolboxTargets.cmake
NAMESPACE numerical-toolbox::
DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/NumericalToolbox
)
configure_package_config_file(
${CMAKE_CURRENT_SOURCE_DIR}/cmake/NumericalToolboxConfig.cmake.in
${CMAKE_CURRENT_BINARY_DIR}/NumericalToolboxConfig.cmake
INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/NumericalToolbox
)
write_basic_package_version_file(
${CMAKE_CURRENT_BINARY_DIR}/NumericalToolboxConfigVersion.cmake
VERSION ${PROJECT_VERSION}
COMPATIBILITY SameMajorVersion
)
install(FILES
${CMAKE_CURRENT_BINARY_DIR}/NumericalToolboxConfig.cmake
${CMAKE_CURRENT_BINARY_DIR}/NumericalToolboxConfigVersion.cmake
${CMAKE_CURRENT_SOURCE_DIR}/cmake/NumericalCompilerOptions.cmake
DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/NumericalToolbox
)
install(FILES
${CMAKE_CURRENT_SOURCE_DIR}/LICENSE
${CMAKE_CURRENT_SOURCE_DIR}/README.md
DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/numerical-toolbox
)
set(CPACK_GENERATOR "ZIP;TGZ")
set(CPACK_SOURCE_IGNORE_FILES ".vs/;.git/;build/")
set(CPACK_PACKAGE_NAME "${PROJECT_NAME}")
set(CPACK_PACKAGE_VERSION "${PROJECT_VERSION}")
set(CPACK_PACKAGE_DESCRIPTION "${PROJECT_DESCRIPTION}")
set(CPACK_DEBIAN_PACKAGE_NAME "${CPACK_PACKAGE_NAME}")
set(CPACK_RPM_PACKAGE_NAME "${CPACK_PACKAGE_NAME}")
set(CPACK_PACKAGE_HOMEPAGE_URL "${PROJECT_HOMEPAGE_URL}")
set(CPACK_PACKAGE_MAINTAINER "${CPACK_PACKAGE_VENDOR}")
set(CPACK_DEBIAN_PACKAGE_MAINTAINER "${CPACK_PACKAGE_VENDOR}")
set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE")
set(CPACK_RESOURCE_FILE_README "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
include(CPack)